# https://nixos.org/manual/nixpkgs/stable/#sec-overlays-definition
{ pkgs, ... }:
[
  # features
  (final: prev: {
    scc = prev.scc.overrideAttrs (old: {
      # https://github.com/boyter/scc/pull/622
      src = pkgs.fetchFromGitHub {
        owner = "boyter";
        repo = "scc";
        rev = "b73ea06bdc5890821d03502a2cfc4224b19a9b67";
        hash = "sha256-vcuoKrvludBE0KpXVLkKzB38n0mZJWVB8bYrgJDHKfY=";
      };
    });
  })
  (final: prev: {
    skim = prev.skim.overrideAttrs (old: {
      patches = old.patches ++ [
        # https://github.com/skim-rs/skim/issues/803
        ../../workstation/patches/skim-blank.patch
      ];
    });
  })

  # bug fixes
  (final: prev: {
    sway-unwrapped = prev.sway-unwrapped.overrideAttrs (old: {
      patches = old.patches ++ [
        # https://github.com/swaywm/sway/pull/8761
        (pkgs.fetchpatch {
          url = "https://github.com/swaywm/sway/commit/af7c6ec7b1daeeec67dd17e27fb75f1f1c347327.patch";
          hash = "sha256-DxN/3IdswZ6q/ksBVr+wgwGe7ScJeg8gFHYQdQAueww=";
        })
      ];
    });
  })
]