tente: replace gotify with grafana-matrix-forwarder

2 files changed, 41 insertions, 0 deletions

diff --git a/nixos/shared/grafana-matrix-forwarder/default.nix b/nixos/shared/grafana-matrix-forwarder/default.nix
new file mode 100644
index 0000000..7a04dcb
--- /dev/null
+++ b/nixos/shared/grafana-matrix-forwarder/default.nix
@@ -0,0 +1,10 @@
+{ buildGoModule }:
+let
+  sources = import <top/npins>;
+in
+buildGoModule {
+  pname = "grafana-matrix-forwarder";
+  version = sources.grafana-matrix-forwarder.version;
+  src = sources.grafana-matrix-forwarder;
+  vendorHash = "sha256-ifkeakyRkIF2Y/4otUWhTvUzsPwRb1Wxx6gqN0806c4=";
+}
diff --git a/nixos/shared/grafana-matrix-forwarder/service.nix b/nixos/shared/grafana-matrix-forwarder/service.nix
new file mode 100644
index 0000000..5ad511c
--- /dev/null
+++ b/nixos/shared/grafana-matrix-forwarder/service.nix
@@ -0,0 +1,31 @@
+{ config, lib, pkgs, ... }:
+
+let
+  grafanaMatrixForwarder = pkgs.callPackage ./default.nix {};
+  cfg = config.services.grafana-matrix-forwarder;
+in
+{
+  options.services.grafana-matrix-forwarder = {
+    enable = lib.mkEnableOption "grafana-matrix-forwarder";
+    port = lib.mkOption {
+      type = lib.types.int;
+    };
+    homeserver = lib.mkOption {
+      type = lib.types.str;
+    };
+    environmentFile = lib.mkOption {
+      type = lib.types.path;
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    systemd.services.grafana-matrix-forwarder = {
+      serviceConfig = {
+        ExecStart = "${grafanaMatrixForwarder}/bin/grafana-matrix-forwarder --port=${toString cfg.port} --homeserver ${cfg.homeserver}";
+        EnvironmentFile = cfg.environmentFile;
+        DynamicUser = "true";
+      };
+      wantedBy = ["multi-user.target"];
+    };
+  };
+}