feat(workstation): add /doc

3 files changed, 37 insertions, 0 deletions

diff --git a/nixos/profiles/workstation/default.nix b/nixos/profiles/workstation/default.nix
index 9332bca..d77d67d 100644
--- a/nixos/profiles/workstation/default.nix
+++ b/nixos/profiles/workstation/default.nix
@@ -19,6 +19,7 @@ in
     ./firefox.nix
     ./dev.nix
     ./create.nix
+    ./doc.nix
     ./llm.nix
   ];
 
diff --git a/nixos/profiles/workstation/doc.nix b/nixos/profiles/workstation/doc.nix
new file mode 100644
index 0000000..1c29ed1
--- /dev/null
+++ b/nixos/profiles/workstation/doc.nix
@@ -0,0 +1,35 @@
+# Many packages include documentation other than man pages.
+# Nixpkgs conventionally installs this under share/doc, which NixOS
+# exposes at /run/current-system/sw/share/doc. Much of it is HTML.
+# This module collects plaintext documentation and exposes it under /doc/,
+# to make it more accessible to terminal users and digestible for LLMs.
+
+{
+  config,
+  pkgs,
+  pkgs-unstable,
+  ...
+}:
+
+let
+  gitDocs = pkgs.runCommand "git-docs" { } ''
+    mkdir -p $out
+    tar --extract --xz --file ${pkgs.git.src} \
+      --strip-components=2 --directory $out \
+      --wildcards '*/Documentation/*.adoc'
+  '';
+  symlinks = {
+    nix = "${config.nix.package.src}/doc/manual/source";
+    git = "${gitDocs}";
+    jj = "${pkgs.jujutsu.src}/docs";
+    pi = "${pkgs-unstable.pi-coding-agent}/lib/node_modules/pi-monorepo/docs";
+  };
+in
+{
+  systemd.tmpfiles.rules = [
+    # /doc is a real directory rather than a symlink so sandbox bind mounts
+    # of /doc keep seeing updated entries when the symlinks inside it change.
+    "d /doc 0555 root root -"
+  ]
+  ++ pkgs.lib.mapAttrsToList (name: target: "L+ /doc/${name} - - - - ${target}") symlinks;
+}
diff --git a/nixos/profiles/workstation/llm.nix b/nixos/profiles/workstation/llm.nix
index ef4a07c..758fe06 100644
--- a/nixos/profiles/workstation/llm.nix
+++ b/nixos/profiles/workstation/llm.nix
@@ -19,6 +19,7 @@ let
       --bind-try /nix/var/nix/daemon-socket /nix/var/nix/daemon-socket
       --dir /run
       --ro-bind-try /run/current-system /run/current-system
+      --ro-bind /doc /doc
       # mount git and jj config
       --ro-bind "$HOME/.config" "$HOME/.config"
       --ro-bind "$HOME/repos/config" "$HOME/repos/config"