service.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

{ config, lib, pkgs, ... }:

let
  geoposShare = pkgs.callPackage ./default.nix {};
  cfg = config.services.geopos-share;
  nginxVhostOptions =
    (import <nixpkgs/nixos/modules/services/web-servers/nginx/vhost-options.nix> {
      inherit config lib;
    }).options;
in
{
  options.services.geopos-share = {
    enable = lib.mkEnableOption "geopos-share";

    virtualHost = lib.mkOption {
      type = lib.types.str;
      description = "Name of the nginx virtualhost to set up.";
    };

    nginx = lib.mkOption {
      type = lib.types.submodule {
        options = lib.removeAttrs nginxVhostOptions ["root"];
      };
      default = {};
    };
  };

  config = lib.mkIf cfg.enable {
    services.nginx = {
      enable = true;

      virtualHosts.${cfg.virtualHost} = lib.mkMerge [
        cfg.nginx
        {
          root = "${geoposShare}";
        }
      ];
    };
  };
}