service.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

{ config, lib, pkgs, ... }:

let
  osm_proposals = pkgs.callPackage ./default.nix {};
  cfg = config.services.osm_proposals;
in
{
  options.services.osm_proposals = {
    enable = lib.mkEnableOption "osm_proposals";

    virtualHost = lib.mkOption {
      type = lib.types.str;
      description = "Name of the nginx virtualhost to set up.";
    };

    nginx = lib.mkOption {
      type = lib.types.submodule (import <nixpkgs/nixos/modules/services/web-servers/nginx/vhost-options.nix>);
      default = {};
    };
  };

  config = lib.mkIf cfg.enable {
    services.nginx = {
      enable = true;

      virtualHosts.${cfg.virtualHost} = lib.mkMerge [
        cfg.nginx
        {
          locations."/" = {
            root = "${osm_proposals}/share/osm-proposals";
          };
          locations."=/proposals.json" = {
            extraConfig = ''
              alias /var/lib/osm-proposals/proposals.json;
            '';
          };
        }
      ];
    };

    systemd.services.osm-proposals = {
      serviceConfig = {
        Type = "oneshot";
        StateDirectory = "osm-proposals"; # creates /var/lib/osm-proposals
        ExecStart = "${osm_proposals}/bin/osm-proposals /var/lib/osm-proposals/proposals.json";
        # Not using DynamicUser because then the StateDirectory becomes unreadable
        # by other users, even when setting StateDirectoryMode for some reason.
      };
      startAt = "hourly";
    };
  };
}